entry.S

  1/* SPDX-License-Identifier: GPL-2.0 */
  2/*
  3 * Copyright (C) 2020-2022 Loongson Technology Corporation Limited
  4 *
  5 * Derived from MIPS:
  6 * Copyright (C) 1994 - 2000, 2001, 2003 Ralf Baechle
  7 * Copyright (C) 1999, 2000 Silicon Graphics, Inc.
  8 * Copyright (C) 2001 MIPS Technologies, Inc.
  9 */
 10
 11#include <asm/asm.h>
 12#include <asm/asmmacro.h>
 13#include <asm/loongarch.h>
 14#include <asm/regdef.h>
 15#include <asm/stackframe.h>
 16#include <asm/thread_info.h>
 17#include <asm/unwind_hints.h>
 18
 19	.text
 20	.cfi_sections	.debug_frame
 21	.align	5
 22SYM_CODE_START(handle_syscall)
 23	UNWIND_HINT_UNDEFINED
 24	csrrd		t0, PERCPU_BASE_KS
 25	la.pcrel	t1, kernelsp
 26	PTR_ADD		t1, t1, t0
 27	move		t2, sp
 28	PTR_L		sp, t1, 0
 29
 30	PTR_ADDI	sp, sp, -PT_SIZE
 31	cfi_st		t2, PT_R3
 32	cfi_rel_offset	sp, PT_R3
 33	LONG_S		zero, sp, PT_R0
 34	csrrd		t2, LOONGARCH_CSR_PRMD
 35	LONG_S		t2, sp, PT_PRMD
 36	csrrd		t2, LOONGARCH_CSR_CRMD
 37	LONG_S		t2, sp, PT_CRMD
 38	csrrd		t2, LOONGARCH_CSR_EUEN
 39	LONG_S		t2, sp, PT_EUEN
 40	csrrd		t2, LOONGARCH_CSR_ECFG
 41	LONG_S		t2, sp, PT_ECFG
 42	csrrd		t2, LOONGARCH_CSR_ESTAT
 43	LONG_S		t2, sp, PT_ESTAT
 44	cfi_st		ra, PT_R1
 45	cfi_st		a0, PT_R4
 46	cfi_st		a1, PT_R5
 47	cfi_st		a2, PT_R6
 48	cfi_st		a3, PT_R7
 49	cfi_st		a4, PT_R8
 50	cfi_st		a5, PT_R9
 51	cfi_st		a6, PT_R10
 52	cfi_st		a7, PT_R11
 53	csrrd		ra, LOONGARCH_CSR_ERA
 54	LONG_S		ra, sp, PT_ERA
 55	cfi_rel_offset	ra, PT_ERA
 56
 57	cfi_st		tp, PT_R2
 58	cfi_st		u0, PT_R21
 59	cfi_st		fp, PT_R22
 60
 61	SAVE_STATIC
 62	UNWIND_HINT_REGS
 63
 64#ifdef CONFIG_KGDB
 65	li.w		t1, CSR_CRMD_WE
 66	csrxchg		t1, t1, LOONGARCH_CSR_CRMD
 67#endif
 68
 69	move		u0, t0
 70	LONG_LI		tp, ~_THREAD_MASK
 71	and		tp, tp, sp
 72
 73	move		a0, sp
 74	bl		do_syscall
 75
 76	STACKLEAK_ERASE
 77	RESTORE_ALL_AND_RET
 78SYM_CODE_END(handle_syscall)
 79_ASM_NOKPROBE(handle_syscall)
 80
 81SYM_CODE_START(ret_from_fork_asm)
 82	UNWIND_HINT_REGS
 83	move		a1, sp
 84	bl 		ret_from_fork
 85	STACKLEAK_ERASE
 86	RESTORE_STATIC
 87	RESTORE_SOME
 88	RESTORE_SP_AND_RET
 89SYM_CODE_END(ret_from_fork_asm)
 90
 91SYM_CODE_START(ret_from_kernel_thread_asm)
 92	UNWIND_HINT_REGS
 93	move		a1, sp
 94	move		a2, s0
 95	move		a3, s1
 96	bl		ret_from_kernel_thread
 97	STACKLEAK_ERASE
 98	RESTORE_STATIC
 99	RESTORE_SOME
100	RESTORE_SP_AND_RET
101SYM_CODE_END(ret_from_kernel_thread_asm)